mirror of
https://github.com/google/sandboxed-api.git
synced 2024-03-22 13:11:30 +08:00
066af80c8b
- Check for Linux (Android TBD once that lands) and C++17 - Move `SAPI_HARDENED_SOURCE` check after compile options are evaluated - Use a more modern way to set the required C++ standard, compatible with Abseil's `ABSL_PROPAGATE_CXX_STD`. - Scope `-fno-exceptions` and `POSITION_INDEPENDENT_CODE` to SAPI targets - Increase maximum stack frame size yet again PiperOrigin-RevId: 422369190 Change-Id: If75405ee43740de90196f52cddc8938482eae851
69 lines
2.5 KiB
CMake
69 lines
2.5 KiB
CMake
# Copyright 2019 Google LLC
|
|
#
|
|
# Licensed under the Apache License, Version 2.0 (the "License");
|
|
# you may not use this file except in compliance with the License.
|
|
# You may obtain a copy of the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS,
|
|
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
# See the License for the specific language governing permissions and
|
|
# limitations under the License.
|
|
|
|
set(workdir "${CMAKE_BINARY_DIR}/_deps/absl-populate")
|
|
|
|
set(SAPI_ABSL_GIT_REPOSITORY https://github.com/abseil/abseil-cpp.git
|
|
CACHE STRING "")
|
|
set(SAPI_ABSL_GIT_TAG d96e287417766deddbff2d01b96321288c59491e
|
|
CACHE STRING "") # 2021-04-23
|
|
set(SAPI_ABSL_SOURCE_DIR "${CMAKE_BINARY_DIR}/_deps/absl-src" CACHE STRING "")
|
|
set(SAPI_ABSL_BINARY_DIR "${CMAKE_BINARY_DIR}/_deps/absl-build" CACHE STRING "")
|
|
|
|
file(WRITE "${workdir}/CMakeLists.txt" "\
|
|
cmake_minimum_required(VERSION ${CMAKE_VERSION})
|
|
project(absl-populate NONE)
|
|
include(ExternalProject)
|
|
ExternalProject_Add(absl
|
|
GIT_REPOSITORY \"${SAPI_ABSL_GIT_REPOSITORY}\"
|
|
GIT_TAG \"${SAPI_ABSL_GIT_TAG}\"
|
|
SOURCE_DIR \"${SAPI_ABSL_SOURCE_DIR}\"
|
|
BINARY_DIR \"${SAPI_ABSL_BINARY_DIR}\"
|
|
CONFIGURE_COMMAND \"\"
|
|
BUILD_COMMAND \"\"
|
|
INSTALL_COMMAND \"\"
|
|
TEST_COMMAND \"\"
|
|
)
|
|
")
|
|
|
|
execute_process(COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" .
|
|
RESULT_VARIABLE error
|
|
WORKING_DIRECTORY "${workdir}")
|
|
if(error)
|
|
message(FATAL_ERROR "CMake step for ${PROJECT_NAME} failed: ${error}")
|
|
endif()
|
|
|
|
execute_process(COMMAND ${CMAKE_COMMAND} --build .
|
|
RESULT_VARIABLE error
|
|
WORKING_DIRECTORY "${workdir}")
|
|
if(error)
|
|
message(FATAL_ERROR "Build step for ${PROJECT_NAME} failed: ${error}")
|
|
endif()
|
|
|
|
set(_sapi_saved_BUILD_TESTING ${BUILD_TESTING})
|
|
|
|
set(ABSL_CXX_STANDARD ${SAPI_CXX_STANDARD} CACHE STRING "" FORCE)
|
|
set(ABSL_ENABLE_INSTALL ON CACHE BOOL "" FORCE)
|
|
set(ABSL_PROPAGATE_CXX_STD ON CACHE BOOL "" FORCE)
|
|
set(ABSL_RUN_TESTS OFF CACHE BOOL "" FORCE)
|
|
set(ABSL_USE_GOOGLETEST_HEAD OFF CACHE BOOL "" FORCE)
|
|
set(BUILD_TESTING OFF) # Avoid errors when re-configuring SAPI
|
|
|
|
add_subdirectory("${SAPI_ABSL_SOURCE_DIR}"
|
|
"${SAPI_ABSL_BINARY_DIR}" EXCLUDE_FROM_ALL)
|
|
|
|
if(_sapi_saved_BUILD_TESTING)
|
|
set(BUILD_TESTING "${_sapi_saved_BUILD_TESTING}")
|
|
endif()
|