# # # # sol3
# The MIT License (MIT)
# 
# Copyright (c) 2013-2018 Rapptz, ThePhD, and contributors
# 
# Permission is hereby granted, free of charge, to any person obtaining a copy of
# this software and associated documentation files (the "Software"), to deal in
# the Software without restriction, including without limitation the rights to
# use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of
# the Software, and to permit persons to whom the Software is furnished to do so,
# subject to the following conditions:
# 
# The above copyright notice and this permission notice shall be included in all
# copies or substantial portions of the Software.
# 
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS
# FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
# COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
# IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
# CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

# # # # sol3 tests - compilation tests

file(GLOB SOL2_COMPILE_TEST_SOURCES source/**/*.cpp)
source_group(compile_test_sources FILES ${SOL2_COMPILE_TEST_SOURCES})

function(CREATE_TEST test_target_name test_name target_sol)
	if (test_name MATCHES ".single")
		add_executable(${test_target_name} source/main.cpp source/forward.cpp source/sol.cpp)
	else()
		add_executable(${test_target_name} ${SOL2_COMPILE_TEST_SOURCES})
	endif()
	set_target_properties(${test_target_name}
		PROPERTIES
		OUTPUT_NAME ${test_name}
		EXPORT_NAME sol2::${test_name})
	target_link_libraries(${test_target_name} ${target_sol})
	
	if (MSVC)
		if (NOT CMAKE_COMPILER_ID MATCHES "Clang")
			target_compile_options(${test_target_name} 
				PRIVATE /bigobj)
		endif()
	else()
		target_compile_options(${test_target_name} 
			PRIVATE -Wno-noexcept-type -pthread)

		if (IS_X86)
			if(MINGW)
				set_target_properties(${test_target_name}
					PROPERTIES
					LINK_FLAGS -static-libstdc++)
			endif()
		endif()	
	endif()
	if (SOL2_CI)
		target_compile_definitions(${test_target_name} 
			PRIVATE SOL2_CI)
	endif()
	if (CMAKE_DL_LIBS)
		target_link_libraries(${test_target_name}
			${CMAKE_DL_LIBS})
	endif()
	target_link_libraries(${test_target_name}
		Threads::Threads ${LUA_LIBRARIES} ${CATCH_LIBRARIES})
	
	add_test(NAME ${test_name} COMMAND ${test_target_name})
	install(TARGETS ${test_target_name} RUNTIME DESTINATION bin)
endfunction(CREATE_TEST)

CREATE_TEST(compile_tests "compile_tests" sol2::sol2)
if (SOL2_TESTS_SINGLE AND SOL2_SINGLE)
	CREATE_TEST(compile_tests_single "compile_tests.single" sol2::sol2_single)
endif()
if (SOL2_TESTS_SINGLE_GENERATED AND SOL2_GENERATE_SINGLE)
	CREATE_TEST(compile_tests_generated_single "compile_tests.single.generated" sol2::sol2_single_generated)
endif()